akshara/PKGBUILD

# Maintainer: Rudra Saraswat <rs2009@ubuntu.com>

pkgname='akshara-git'
pkgver=r59.9f2f25b
pkgrel=1
pkgdesc="An update system for operating systems"
arch=('x86_64' 'i686')
url="https://github.com/blend-os/blend"
license=('GPL3')
makedepends=('git' 'base-devel')
source=('git+https://git.blendos.co/blendOS/system-tools/akshara')
sha256sums=('SKIP')

depends=('bash' 'python' 'python-lockfile' 'python-psutil' 'python-fasteners' 'python-yaml' 'squashfs-tools' 'wget' 'python-requests' 'arch-install-scripts')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")

pkgver() {
    cd "${srcdir}/${pkgbase%-git}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    cd "${srcdir}/${pkgbase%-git}"
    install -Dm755 \
        "${pkgname%-git}" \
        -t "${pkgdir}"/usr/bin/
    install -Dm644 "${pkgname%-git}.service" -t \
        "${pkgdir}"/usr/lib/systemd/system/
    install -Dm644 "${pkgname%-git}-system-update.service" -t \
        "${pkgdir}"/usr/lib/systemd/system/
    install -Dm644 "${pkgname%-git}.hook" \
        "${pkgdir}/usr/lib/initcpio/hooks/${pkgname%-git}"
    install -Dm644 "${pkgname%-git}.install" \
        "${pkgdir}/usr/lib/initcpio/install/${pkgname%-git}"
}